I was wondering if it is possible to play a wav file when the value of a cell
changes.
If so, how can I do this?
Any suggestions would help, thanks!

This should do it. In your worksheet place this code...

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$1" Then
PlayWavFile "C:\Windows\Media\Microsoft Office 2000\Chimes.wav"
End If
End Sub

In a standard Code Module add this code...
'*******************************************
Private Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
(ByVal lpszName As String, hModule As Long, ByVal dwFlags As Long) As Long

Public Function PlayWavFile(WavFile As String) As String
Const SND_ASYNC = &H1
Const SND_FILENAME = &H20000
PlaySound WavFile, 0, SND_ASYNC Or SND_FILENAME
PlayWavFile = ""
End Function
'**************************************************

--
HTH...

Jim Thomlinson


"Ruben" wrote:

> I was wondering if it is possible to play a wav file when the value of a cell
> changes.
> If so, how can I do this?
> Any suggestions would help, thanks!

"Ruben" <(E-Mail Removed)> wrote in message
news:C1911437-AA69-4B92-B386-(E-Mail Removed)...
>I was wondering if it is possible to play a wav file when the value of a
>cell
> changes.
> If so, how can I do this?
> Any suggestions would help, thanks!

Hi Ruben

You can also coax Excel to issue a vocal warning when the target cell
changes


Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$1" Then
Application.Speech.Speak "The cell contents have changed"
End If
End Sub



Regards N10