I recently installed Office 2007. I have about 700 files in the .html format
and I want to convert them into Office .docx files. I know how to do this on
a single basis but I would like to know if I can do a batch conversion. The
..html files are email letters that I want to put into .docx format so I can
write a book. Any Ideas?
thanks
Paul

The following macro will convert all the files from a folder selected from
the macro. Ensure that Word Options > Advanced > General > Confirm file
conversion on open is NOT checked or you will have to confirm 700 times! -
http://www.gmayor.com/installing_macro.htm

Sub SaveAllAsDOCX()
Dim strFileName As String
Dim strDocName As String
Dim strPath As String
Dim oDoc As Document

With Dialogs(wdDialogCopyFile)
If .Display <> 0 Then
strPath = .Directory
Else
MsgBox "Cancelled by User"
Exit Sub
End If
End With

If Documents.Count > 0 Then
Documents.Close SaveChanges:=wdPromptToSaveChanges
End If
If Left(strPath, 1) = Chr(34) Then
strPath = Mid(strPath, 2, Len(strPath) - 2)
End If
strFileName = Dir$(strPath & "*.htm")

While Len(strFileName) <> 0
Set oDoc = Documents.Open(strPath & strFileName)

strDocName = ActiveDocument.FullName
intPos = InStrRev(strDocName, ".")
strDocName = Left(strDocName, intPos - 1)
strDocName = strDocName & ".docx"
oDoc.SaveAs FileName:=strDocName, _
FileFormat:=wdFormatDocumentDefault
oDoc.Close SaveChanges:=wdDoNotSaveChanges
strFileName = Dir$()
Wend
End Sub


--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP

My web site www.gmayor.com
Word MVP web site http://word.mvps.org
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>

Raroboy wrote:
> I recently installed Office 2007. I have about 700 files in the .html
> format and I want to convert them into Office .docx files. I know how
> to do this on a single basis but I would like to know if I can do a
> batch conversion. The .html files are email letters that I want to
> put into .docx format so I can write a book. Any Ideas?
> thanks
> Paul